#!/bin/csh
# rsync microlens lightcurve data for specific event
set event = $1
set file = $PLENS/rsync_pwd
set from = ML_RsyncNet@mlrsync-stand.net
echo "#######################################"
date
echo rsync_event $1 fetches microlens lightcurve data

# event
if( $event == "" ) then 
	echo -n "Event (e.g. KB09250) : "
	set event = $<
endif

#echo rsync microlens lightcurve data for $event

set survey = `echo $event | cut -c1-2`
set yr = `echo $event | cut -c3-4`
set seq = `echo $event | cut -c5-`

echo event $event survey $survey yr $yr seq $seq

set pass = Y

# sanity check year
if( $yr >= 0 && $yr <= 50 ) then
	set year = '20'$yr
else if( $yr <= 51 && $yr <=99 ) then
	set year = '19'$yr
else
	echo Invalid year $yr "  :((("
	set pass = N
endif

# sanity check (upcase) survey
if( $survey == "ob" ) then
	set survey = OB
else if( $survey == "kb" || $survey == MB || $survey == mb ) then
	set survey = KB
endif
if ( $survey != "OB" && $survey != "KB" ) then
	echo Survey $survey not recognised "  :(((("
	set pass = N
endif

# check seq
if( $seq <= 0 || $seq >= 999 ) then
	echo Event $seq out of range "0-999  :(((("
	set pass = N
endif

if( $pass == Y ) then

 set event = $survey$yr$seq
 set from = $from'::Data'$year
 echo event $event year $year from $from

 echo
 echo rsync $from/\?$event\?.dat
 rsync -avz --password-file=$file $from/\?$event\?.dat .

 echo
 echo rsync $from/multiples.list
 rsync -avz --password-file=$file $from/multiples.list .

 echo
 echo rsync_event finished.
else

 echo rsync_event aborted.
endif

date
echo "#######################################"